#! /usr/bin/perl

=head1 LICENSE

Copyright (c) 2011, Peter S. May

Permission is hereby granted, free of charge, to any person obtaining a copy of
this software and associated documentation files (the "Software"), to deal in
the Software without restriction, including without limitation the rights to
use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies
of the Software, and to permit persons to whom the Software is furnished to do
so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.

=cut

use warnings;
use strict;
use 5.010;
use Carp;

use HTML::Entities ();
use Math::Trig;

my %user_options = (
	count => 10,
);

#####

# Used when not set by %user_options
my %default_options = (
	count => 3, # number of pairs
	size => 1000, # in pixels
	size_hub => 0.02, # ratio to size of circle
	size_text => 50, # in pixels
	offset_text => 25, # in pixels
	style_a => "fill:white;",
	style_b => "fill:black;",
	style_backdrop => "opacity: 0.5; fill: #808080;",
	style_hub => "opacity: 0.5; fill: #808080;",
);

my %opt = %default_options;
$opt{$_} = $user_options{$_} for keys %user_options;

$opt{half_size} = $opt{size} / 2;

# Conversions between circles and other angular units
# 1 cir = 2*pi rad = 360 deg
sub cir2deg($) { return $_[0] * 360; }
sub deg2cir($) { return $_[0] / 360; }
sub cir2rad($) { return $_[0] * 2 * pi; }
sub rad2cir($) { return $_[0] / (2 * pi); }

# Location of angle on a unit circle
sub cossincir($) {
	my $cir = shift;
	my $rad = cir2rad($cir);
	return (cos($rad), sin($rad));
}

# Remove exponential notation from a number
sub fix($) {
	for(sprintf('%f',$_[0])) {
		return "0" if $_ == 0;
		s/0+$//;
		s/\.$//;
		return $_;
	}
}

my $circles_per_pair = 1 / $opt{count};
my $circles_per_wedge = $circles_per_pair / 2;
($opt{arc_end_x},$opt{arc_end_y}) = cossincir($circles_per_wedge);
$opt{degrees_per_pair} = cir2deg($circles_per_pair);
$opt{degrees_per_wedge} = cir2deg($circles_per_wedge);

$opt{text_x} = $opt{offset_text};
$opt{text_y} = $opt{size} - $opt{offset_text};

# Ensure that style attributes are XML-safe
for(qw/style_a style_b style_backdrop style_hub/) {
	next unless defined $opt{$_};
	$opt{$_} = HTML::Entities::encode_numeric($opt{$_});
}
# Ensure that numeric figures are in non-exponential form
for(qw/count size half_size arc_end_x arc_end_y degrees_per_pair degrees_per_wedge text_x text_y size_text/) {
	next unless defined $opt{$_};
	$opt{$_} = fix($opt{$_});
}

print <<EOF ;
<?xml version="1.0" encoding="UTF-8"?>
<svg
	xmlns="http://www.w3.org/2000/svg"
	xmlns:xlink="http://www.w3.org/1999/xlink"
	height="100%"
	width="100%"
	version="1.1"
	viewBox="0 0 $opt{size} $opt{size}"
	>
	<!-- transform to make the coord system more math-friendly -->
	<!--
		transform changes center of page to 0,0 and scales edges to ones,
		but does not flip y, so top of page is y=-1 and bottom is y=1.
	-->
	<g transform="translate($opt{half_size} $opt{half_size}) scale($opt{half_size} $opt{half_size})">
		<!-- y is flipped here for shapes -->
		<g transform="scale(1 -1)">
			<rect
				id="backdrop"
				style="$opt{style_backdrop}"
				height="2"
				width="2"
				x="-1"
				y="-1"
				/>
			<g id="wedgePair">
				<g style="display:none">
					<path
						id="protoWedge"
						d="
							M	1,0
							A	1,1,0,0,1,$opt{arc_end_x},$opt{arc_end_y}
							L	0,0
							z
						"
						/>
				</g>
				<use
					xlink:href="#protoWedge"
					style="$opt{style_a}"
					/>
				<use
					xlink:href="#protoWedge"
					style="$opt{style_b}"
					transform="rotate($opt{degrees_per_wedge},0,0)"
					/>
			</g>
EOF

# Output clones of the first pair as necessary to fill the circle
for(1 .. $opt{count} - 1) {
	my $deg = fix($opt{degrees_per_pair} * $_);
	print<<EOF;
			<use xlink:href="#wedgePair" transform="rotate($deg,0,0)" />
EOF
}

print <<EOF ;
			<path
				id="hub"
				style="$opt{style_hub}"
				d="
					M	1,0
					A	1,1,0,0,0,-1,0
					,	1,1,0,0,0,1,0
					z
				"
				transform="scale($opt{size_hub},$opt{size_hub})"
				/>
		</g>
	</g>
	<text
		style="
			font-size:$opt{size_text}px;
			font-family:sans-serif;
			writing-mode:lr-tb;
			fill:#000;
			letter-spacing:0px;
			text-anchor:start;
			line-height:125%;
			word-spacing:0px;
			font-stretch:normal;
			font-variant:normal;
			font-weight:normal;
			font-style:normal;
			text-align:start;
		"
		y="$opt{text_y}"
		x="$opt{text_x}"
		xml:space="preserve"><tspan id="cycleCount">$opt{count}</tspan></text>
</svg>

EOF